// **********************************************************************
//                   Экзотические хвосты
//
// **********************************************************************
// **********************************************************************
//                   хвост_be
// **********************************************************************
@Перевод
{
   @Структура  to_сущ = @0[to] гр_сущ_а ;
   @Структура  to_сущ = гр_сущ_а( %Д ) ;
}

@Перевод
{
   @Выбор      _to_сущ = to_сущ @00;
   @Выбор      _to_сущ = to_сущ @00;
}

@Перевод
{
   @Структура  to_be = @0[to] @0[be] ;
   @Структура  to_be = @0[_] ;
}

@Перевод
{
   @Выбор      _to_be = to_be @00;
   @Выбор      _to_be = to_be @00;
}

@Перевод
{
   @Структура  прил_сравн_1 = прил_сравн @0[than] гр_сущ_а ;
   @Структура  прил_сравн_1 = прил_сравн @0[чем] гр_сущ_а( %И ) ;
}

@Перевод
{
   @Структура  прил_сравн_2 = гр_сущ_а прил_сравн @0[than] гр_сущ_а ;
   @Структура  прил_сравн_2 = 
               @0[на] гр_сущ_а( %И ) прил_сравн @0[чем] гр_сущ_а( %И ) ;
}

@Перевод
{
   @Структура  прил_сравн_3 = @0[as] прил( &S ) @0[as] гр_сущ_а ;
   @Структура  прил_сравн_3( число &Ч, род &Р, душа &Д, падеж &П ) = 
               @0[такой_же] прил( Р, Д, П, Ч ) @0[как] гр_сущ_а( %И ) ;
}

@Перевод
{
   @Структура  прил_сравн_4 = @0[not] @0[as] прил( &S ) @0[as] гр_сущ_а ;
   @Структура  прил_сравн_4( число &Ч, род &Р, душа &Д, падеж &П ) = 
               @0[не_такой] прил( Р, Д, П, Ч ) @0[как] гр_сущ_а( %И ) ;
}

@Перевод
{
   @Структура  прил_сравн_5 = 
               гр_числительного2 @0[times] @0[as] прил( &S ) @0[as] гр_сущ_а ;
   @Структура  прил_сравн_5( число &Ч, род &Р, душа &Д, падеж &П ) = 
               гр_числительного2( %Ед, &Падеж ) 
               сущ[раз] ( &Р, &Д, Падеж, %Ед ) 
               прил( Р, Д, П, Ч ) 
               @0[чем] 
               гр_сущ_а( %И ) 
               ;
   @Таблица_приемника( ч_падеж Падеж1, падеж Падеж = падеж Падеж2 )
   {
      Уступаю И = И ;
      Уступаю Р = Р ;
      Уступаю Д = Д ;
      Уступаю В = В ;
      Уступаю Т = Т ;
      Уступаю П = П ;

      РВсе @0 = Р ;

      Р И = Р ;
      Р Р = Р ;
      Р Д = Д ;
      Р В = Р ;
      Р Т = Т ;
      Р П = П ;
   };
   @Таблица_приемника( ч_число Число1, падеж Падеж = число Число2 )
   {  Ед @0 = Ед ;
      Мн @0 = Мн ;
      ЕдИ И = Ед ;
      ЕдИ Р = Мн ;
      ЕдИ Д = Мн ;
      ЕдИ В = Ед ;
      ЕдИ Т = Мн ;
      ЕдИ П = Мн ;
   }
}

@Перевод
{
   @Выбор      хвост_be_b = 
               гр_сущ_а                 // Ich bin dubina
               опр_прилагательный1      // good
               мест_сущ1( &Р, &Л, &Ч )  // It is she
               мест_сущ2                // It is me
               гр_наречия               // far from ripe = далеко от созревания
               гр_квази_наречия         // hard to crack
               гр_квази_наречия_предлог 
               гр_прил_предлог 
	       // ------- хвосты сравнительной степени -------------
               прил_сравн 
               прил_сравн_1 
               прил_сравн_2 
               прил_сравн_3 
               прил_сравн_4 
               прил_сравн_5 
               @00                       // Nobody knows whose it is.
               ;
   @Выбор      хвост_be_b( число &Число, род &Род, душа &Душа, падеж &Падеж ) = 
               гр_сущ_а( Падеж ) 
               опр_прилагательный1( Род, Душа, Падеж, Число ) 
               мест_сущ1( &Род1, &Лицо, &Число1, Падеж ) 
               мест_сущ2( Падеж ) 
               гр_наречия 
               гр_квази_наречия 
               гр_квази_наречия_предлог( Род, Число ) 
               гр_прил_предлог( Род, Душа, Падеж, Число ) 
	       // ------- хвосты сравнительной степени -------------
               прил_сравн 
               прил_сравн_1 
               прил_сравн_2 
               прил_сравн_3( Число, Род, Душа, Падеж ) 
               прил_сравн_4( Число, Род, Душа, Падеж ) 
               прил_сравн_5( Число, Род, Душа, Падеж ) 
               @00
               ;

}

@Перевод
{
   @Структура  хвост_be_a = _to_сущ _to_be хвост_be_b ;
   @Структура  хвост_be_a( число &Число, род &Род, душа &Душа, падеж &Падеж ) = 
               _to_сущ _to_be хвост_be_b( Число, Род, Душа, Падеж ) ;
}

@Перевод
{
   @Структура  хвост_be = хвост_be_a _обстоятельство ;
   @Структура  хвост_be( число &Число, род &Род, душа &Душа, падеж &Падеж ) = 
               хвост_be_a( Число, Род, Душа, Падеж ) _обстоятельство ;
}

// **********************************************************************
//                   хвост для there_is
// **********************************************************************
@Перевод
{
// ----- для there_is -------
   @Выбор      хвост_there_a = гр_сущ_в предлог_сущ @00;
   @Выбор      хвост_there_a( число Число, падеж &Падеж, род Род ) = 
               гр_сущ_в( &Число, Падеж, &Род ) предлог_сущ @00;
}

// **********************************************************************
//            хвост have
// **********************************************************************
@Перевод
{
   @Структура  have_пассив = гр_сущ_б глагол( &S1, %Form3 ) ;
   @Структура  have_пассив( число Число, падеж &Падеж, род Род ) = 
               гр_сущ_б( &Число, &Лицо, %И, &Род ) 
               глагол( %Несов, %глагол, @0, Число, @0, Род, %Пассив, @0 ) 
               ;
}

@Перевод
{
   @Выбор      хвост_have_а = гр_сущ_в have_пассив ;
   @Выбор      хвост_have_а( число Число, падеж &Падеж, род Род ) = 
               гр_сущ_в( &Число, Падеж, &Род ) 
               have_пассив( &Число, Падеж, &Род ) 
               ;
}

@Перевод
{
   @Структура  хвост_have = хвост_have_а _обстоятельство ;
   @Структура  хвост_have( число Число, падеж &Падеж, род Род ) = 
               хвост_have_а( &Число, Падеж, &Род ) _обстоятельство ;
}