Macro: ac_prog_javah

Back to the Main Page. | Download the M4 Source.

# ac_prog_javah

## Synopsis

`AC_PROG_JAVAH`

## Version

1.1.1.1 (2001/07/26) Java_Support @ ac-archive-0.5.32

## Author

Luc Maisonobe

## Description

AC_PROG_JAVAH tests the availability of the javah header generator and looks for the jni.h header file. If available, JAVAH is set to the full path of javah and CPPFLAGS is updated accordingly.

## M4 Source Code

    AC_DEFUN([AC_PROG_JAVAH],[
    AC_REQUIRE([AC_CANONICAL_SYSTEM])dnl
    AC_REQUIRE([AC_PROG_CPP])dnl
    AC_PATH_PROG(JAVAH,javah)
    if test x"`eval 'echo $ac_cv_path_JAVAH'`" != x ; then
      AC_TRY_CPP([#include <jni.h>],,[
        ac_save_CPPFLAGS="$CPPFLAGS"
    changequote(, )dnl
        ac_dir=`echo $ac_cv_path_JAVAH | sed 's,\(.*\)/[^/]*/[^/]*$,\1/include,'`
        ac_machdep=`echo $build_os | sed 's,[-0-9].*,,'`
    changequote([, ])dnl
        CPPFLAGS="$ac_save_CPPFLAGS -I$ac_dir -I$ac_dir/$ac_machdep"
        AC_TRY_CPP([#include <jni.h>],
                   ac_save_CPPFLAGS="$CPPFLAGS",
                   AC_MSG_WARN([unable to include <jni.h>]))
        CPPFLAGS="$ac_save_CPPFLAGS"])
    fi])