Macro: stdrelpaths

Back to the Main Page. | Download the M4 Source.

# stdrelpaths

## Synopsis

`adl_COMPUTE_STANDARD_RELATIVE_PATHS`

## Version

1.1 (2001/07/26) adl @ ac-archive-0.5.32

## Author

Alexandre Duret-Lutz <duret_g@epita.fr>

## Description

Here is the standard hierarchy of paths, as defined by the GNU Coding Standards:

`prefix`
`exec_prefix`
`bindir`
`libdir`
`libexecdir`
`sbindir`
`datadir`
`sysconfdir`
`sharestatedir`
`localstatedir`
`infodir`
`lispdir`
`includedir`
`oldincludedir`
`mandir`

This macro will setup a set of variables of the form 'xxx_forward_relative_path' and 'xxx_backward_relative_path' where xxx is one of the above directories. The latter variable is set to the relative path to go from xxx to its parent directory, while the former hold the other way.

For instance `bindir_relative_path' will contains the value to add to $exec_prefix to reach the $bindir directory (usually 'bin'), and `bindir_backward_relative_path' the value to append to $bindir to reach the $exec_prefix directory (usually '..').

This macro requires adl_COMPUTE_RELATIVE_PATHS which itself requires adl_NORMALIZE_PATH.

## M4 Source Code

    AC_DEFUN([adl_COMPUTE_STANDARD_RELATIVE_PATHS],
    ## These calls need to be on separate lines for aclocal to work!
    [adl_COMPUTE_RELATIVE_PATHS(dnl
    adl_STANDARD_RELATIVE_PATH_LIST)])

    dnl adl_STANDARD_RELATIVE_PATH_LIST
    dnl ===============================
    dnl A list of standard paths, ready to supply to adl_COMPUTE_RELATIVE_PATHS.
    AC_DEFUN([adl_STANDARD_RELATIVE_PATH_LIST],
    [pushdef([TRIPLET],
    [$][1:$][2:$][2_forward_relative_path $]dnl
    [2:$][1:$][2_backward_relative_path])dnl
    TRIPLET(prefix, exec_prefix) dnl
    TRIPLET(exec_prefix, bindir) dnl
    TRIPLET(exec_prefix, libdir) dnl
    TRIPLET(exec_prefix, libexecdir) dnl
    TRIPLET(exec_prefix, sbindir) dnl
    TRIPLET(prefix, datadir) dnl
    TRIPLET(prefix, sysconfdir) dnl
    TRIPLET(prefix, sharestatedir) dnl
    TRIPLET(prefix, localstatedir) dnl
    TRIPLET(prefix, infodir) dnl
    TRIPLET(prefix, lispdir) dnl
    TRIPLET(prefix, includedir) dnl
    TRIPLET(prefix, oldincludedir) dnl
    TRIPLET(prefix, mandir) dnl
    popdef([TRIPLET])])