Macro: adl_func_getopt_long

Back to the Main Page. | Download the M4 Source.

# adl_func_getopt_long

## Synopsis

`adl_FUNC_GETOPT_LONG`

## Version

1.1.1.1 (2001/07/26) Installed_Packages @ ac-archive-0.5.32

## Author

Alexandre Duret-Lutz <duret_g@epita.fr>

## Description

Check for getopt_long support.

This assume that the standard getopt.h file (from GNU libc) is available as lib/gnugetopt.h. If needed, this file will be linked as getopt.h, but we want to default to the system's getopt.h file. (See http://sources.redhat.com/ml/automake/2000-09/msg00041.html for an explanation about why using the system's getopt.h file is important.)

## M4 Source Code

    AC_PREREQ(2.49)

    AC_DEFUN([adl_FUNC_GETOPT_LONG],
     [# clean out junk possibly left behind by a previous configuration
      rm -f lib/getopt.h
      # Check for getopt_long support
      AC_CHECK_HEADER([getopt.h])
      AC_CHECK_FUNCS([getopt_long],,
       [# FreeBSD has a gnugetopt library for this
        AC_CHECK_LIB([gnugetopt],[getopt_long],[AC_DEFINE([HAVE_GETOPT_LONG])],
         [# use the GNU replacement
          AC_LIBOBJ(getopt)
          AC_LIBOBJ(getopt1)
          AC_CONFIG_LINKS([lib/getopt.h:lib/gnugetopt.h])])])])