Macro: ac_cxx_mutable

Back to the Main Page. | Download the M4 Source.

# ac_cxx_mutable

## Synopsis

`AC_CXX_MUTABLE`

## Version

1.1.1.1 (2001/07/26) C++_Support @ ac-archive-0.5.32

## Author

Luc Maisonobe

## Description

If the compiler allows modifying class data members flagged with the mutable keyword even in const objects (for example in the body of a const member function), define HAVE_MUTABLE.

## M4 Source Code

    AC_DEFUN([AC_CXX_MUTABLE],
    [AC_CACHE_CHECK(whether the compiler supports the mutable keyword,
    ac_cv_cxx_mutable,
    [AC_LANG_SAVE
     AC_LANG_CPLUSPLUS
     AC_TRY_COMPILE([
    class A { mutable int i;
              public:
              int f (int n) const { i = n; return i; }
            };
    ],[A a; return a.f (1);],
     ac_cv_cxx_mutable=yes, ac_cv_cxx_mutable=no)
     AC_LANG_RESTORE
    ])
    if test "$ac_cv_cxx_mutable" = yes; then
      AC_DEFINE(HAVE_MUTABLE,,[define if the compiler supports the mutable keyword])
    fi
    ])