dnl $Header: /cvs/faces/faces/configure.in,v 1.7 2002/02/21 15:42:54 devface Exp $
dnl
dnl  Copyright (C) 1990-2002  Rich Burridge, Sun Microsystems Inc.
dnl  All rights reserved.
dnl 
dnl  Permission is given to distribute these sources, as long as the
dnl  copyright messages are not removed, and no monies are exchanged.
dnl 
dnl  No responsibility is taken for any errors on inaccuracies inherent
dnl  either to the comments or the code of this program, but if reported
dnl  to me, then an attempt will be made to fix them.

dnl Process this file with autoconf to produce a configure script.

AC_INIT(configure.in)
AM_INIT_AUTOMAKE(faces, 1.7.7)
AC_CONFIG_SRCDIR([faces/get.c])
AM_CONFIG_HEADER(config.h)

# Checks for programs.
AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AC_HEADER_STDC
AC_PROG_INSTALL
AC_PROG_RANLIB
AC_PROG_YACC

# Checks for header files.
AC_PATH_XTRA
AC_HEADER_STDC
AC_CHECK_HEADERS([fcntl.h netdb.h stdlib.h string.h sys/file.h sys/param.h sys/socket.h sys/stat.h sys/time.h unistd.h utime.h])

# Checks for typedefs, structures, and compiler characteristics.
AC_HEADER_TIME

# Checks for library functions.
AC_FUNC_MALLOC
AC_TYPE_SIGNAL
AC_FUNC_STAT
AC_CHECK_FUNCS([endpwent getcwd gethostbyname isascii memset strcasecmp strchr strrchr])

AM_PATH_GTK(1.2.0, ,
            AC_MSG_ERROR(Cannot find GTK: Is gtk-config in path?))

dnl Add the languages which your application supports here.
ALL_LINGUAS=""
AM_GNU_GETTEXT

dnl Set PACKAGE_LOCALE_DIR in config.h.
if test "x${prefix}" = "xNONE"; then
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${ac_default_prefix}/${DATADIRNAME}/locale")
else
  AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR, "${prefix}/${DATADIRNAME}/locale")
fi

dnl Set PACKAGE_DATA_DIR in config.h.
if test "x${datadir}" = 'x${prefix}/share'; then
  if test "x${prefix}" = "xNONE"; then
    AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${ac_default_prefix}/share/${PACKAGE}")
  else
    AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${prefix}/share/${PACKAGE}")
  fi
else
  AC_DEFINE_UNQUOTED(PACKAGE_DATA_DIR, "${datadir}/${PACKAGE}")
fi

dnl Set PACKAGE_SOURCE_DIR in config.h.
packagesrcdir=`cd $srcdir && pwd`
AC_DEFINE_UNQUOTED(PACKAGE_SOURCE_DIR, "${packagesrcdir}")

dnl Use -Wall if we have gcc.
changequote(,)dnl
if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \	]-Wall[\ \	]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac
fi
changequote([,])dnl

AC_ARG_ENABLE(imap,
  AC_HELP_STRING([--enable-imap],
                 [enable IMAP mail retrieval (default=disable)]),
  enable_imap="$enableval", enable_imap=no)
if test "$enable_imap" = yes; then
  AC_DEFINE(IMAP, 1, [include IMAP mail retrieval])
fi

AC_ARG_ENABLE(pop,
  AC_HELP_STRING([--enable-pop],
                 [enable POP mail retrieval (default=disable)]),
  enable_pop="$enableval", enable_pop=no)
if test "$enable_pop" = yes; then
  AC_DEFINE(POP, 1, [include POP mail retrieval])
fi

AC_ARG_ENABLE(audio,
  AC_HELP_STRING([--enable-audio],
                 [enable audio support (default=disable)]),
  enable_audio="$enableval", enable_audio=no)
if test "$enable_audio" = yes; then
  AC_DEFINE(AUDIO_SUPPORT, 1, [include audio support])
fi

AC_ARG_ENABLE(dns-lookup,
  AC_HELP_STRING([--enable-dns-lookup],
                 [enable DNS lookup to qualify hostnames (default=disable)]),
  enable_dns="$enableval", enable_dns=no)
AM_CONDITIONAL(DNSLOOKUP, test "$enable_dns" = yes)
if test "$enable_dns" = yes; then
  AC_DEFINE(DNSLOOKUP, 1, [include DNS lookup support])
fi

AC_ARG_ENABLE(name-unknown,
  AC_HELP_STRING([--enable-name-unknown],
                 [label unknown name as "unknown" (default=disable)]),
  enable_unknown="$enableval", enable_unknown=no)
if test "$enable_unknown" = yes; then
  AC_DEFINE(NAMEUNKNOWN, 1, [label unknown name as "unknown"])
fi

AC_ARG_ENABLE(nis-lookup,
  AC_HELP_STRING([--enable-nis-lookup],
                 [use NIS to resolve machine.tab hostnames (default=disable)]),
  enable_nis="$enableval", enable_nis=no)
if test "$enable_nis" = yes; then
  AC_DEFINE(NISLOOKUP, 1, [use NIS to resolve machine.tab hostnames])
fi

AC_ARG_ENABLE(show-number,
  AC_HELP_STRING([--disable-show-number],
                 [disable showing number of messages (default=enable)]),
  enable_number="$enableval", enable_number=yes)
if test "$enable_number" != yes; then
  AC_DEFINE(DONTSHOWNO, 1, [disable showing number of messages])
fi

AC_ARG_ENABLE(show-time,
  AC_HELP_STRING([--disable-show-time],
                 [disable showing message timestamps (default=enable)]),
  enable_time="$enableval", enable_time=yes)
if test "$enable_time" != yes; then
  AC_DEFINE(DONTSHOWTIME, 1, [disable showing message timestamps])
fi

AC_ARG_ENABLE(show-user,
  AC_HELP_STRING([--disable-show-user],
                 [disable showing message username (default=enable)]),
  enable_user="$enableval", enable_user=yes)
if test "$enable_user" != yes; then
  AC_DEFINE(DONTSHOWUSER, 1, [disable showing message username])
fi

AC_ARG_ENABLE(domains,
  AC_HELP_STRING([--disable-domains],
                 [disable full domain name search (default=enable)]),
  enable_domains="$enableval", enable_domains=yes)
if test "$enable_domains" != yes; then
  AC_DEFINE(NODOMAINS, 1, [disable full domain name search])
fi

AC_ARG_WITH(audio_cmd,
  AC_HELP_STRING([--with-audio-cmd=CMD],
                 [alternate command for playing audio]),
  audio_cmd="$withval", audio_cmd="")
if test "$audio_cmd" != ""; then
  AC_DEFINE_UNQUOTED(AUDIO_CMD, "$audio_cmd",
                     [alternate command for playing audio])
fi

AC_ARG_WITH(background,
  AC_HELP_STRING([--with-background=FILE],
                 [alternate background image file]),
  background="$withval", background="")
if test "$background" != ""; then
  AC_DEFINE_UNQUOTED(BACKGROUND, "$background",
                     [alternate background image file])
fi

AC_ARG_WITH(facedir,
  AC_HELP_STRING([--with-facedir=DIR],
                 [alternate faces database directory]),
  facedir="$withval", facedir="")
if test "$facedir" != ""; then
  AC_DEFINE_UNQUOTED(FACEDIR, "$facedir",
                     [alternate faces database directory])
fi

AC_ARG_WITH(spooldir,
  AC_HELP_STRING([--with-spooldir=DIR],
                 [alternate mail spool directory]),
  spooldir="$withval", spooldir="")
if test "$spooldir" != ""; then
  AC_DEFINE_UNQUOTED(SPOOLDIR, "$spooldir",
                     [alternate mail spool directory])
fi

AC_ARG_WITH(spoolfile,
  AC_HELP_STRING([--with-spoolfile=FILE],
                 [alternate mail spool file]),
  spoolfile="$withval", spoolfile="")
if test "$spoolfile" != ""; then
  AC_DEFINE_UNQUOTED(SPOOLFILE, "$spoolfile",
                     [alternate mail spool file])
fi

AC_ARG_WITH(period,
  AC_HELP_STRING([--with-period=SECS],
                 [mail spool polling period]),
  period="$withval", period="")
if test "$period" != ""; then
  AC_DEFINE_UNQUOTED(PERIOD, "$period",
                     [mail spool polling period])
fi

AC_C_BIGENDIAN
if test "$ac_cv_c_bigendian" != yes; then
   AC_DEFINE(REVORDER, 1, [build for little-endian machines])
fi

AC_OUTPUT([
Makefile
faces/Makefile
compface/Makefile
intl/Makefile
po/Makefile.in
])