Introducedilhaão às Equacedilhaões Diferenciais
===============================================

Esta secção descreve as funções disponíveis no Maxima para obter a solução analítica de alguns tipos específicos de equações diferencias de primeira e segunda ordem. Para obter a solução numérica dum sistema de equações diferenciais, consulte o pacote adicional dynamics. Para obter representações gráficas no espaço de fase, consulte o pacote adicional plotdf.

Definicedilhaões para Equacedilhaões Diferenciais
=================================================

 -- Funcedilhaão: bc2 (SOLUCEDILHAÃO, XVAL1, YVAL1, XVAL2, YVAL2)
     Resolve um problema de valores fronteira para uma equação diferencial de segunda ordem.  Aqui: SOLUCEDILHAÃO é uma solucedilhaão geral para a equacedilhaão, calculada por ode2; XVAL1 define o valor da variável independente, num primeiro ponto, na forma X = X1, e YVAL1 define o valor da variável dependente, no mesmo ponto, na forma Y = Y1. As expressões XVAL2 e YVAL2 definem os valores das mesmas variáveis, num segundo ponto, usando a mesma forma.

     Veja um exemplo da sua utilização na documentação de ode2.

 -- Funcedilhaão: desolve (EQN, X)
 -- Funcedilhaão: desolve ([EQN_1, ..., EQN_N], [X_1, ..., X_N])
     A funcedilhaão dsolve resolve sistemas de equações diferenciais ordinárias lineares usando transformada de Laplace. Aqui as expressões EQN são equações diferenciais nas variáveis dependentes X_1, ..., X_N.  A relação funcional de X_1, ..., X_N na variável independente deve ser indicada explicitamente nas variáveis e nas suas derivadas. Por exemplo, esta forma de definir as equações não seria correcta:

          eqn_1: 'diff(f,x,2) = sin(x) + 'diff(g,x);
          eqn_2: 'diff(f,x) + x^2 - f = 2*'diff(g,x,2);

     A forma correcta seria:

          eqn_1: 'diff(f(x),x,2) = sin(x) + 'diff(g(x),x);
          eqn_2: 'diff(f(x),x) + x^2 - f(x) = 2*'diff(g(x),x,2);

     Assim, a chamada à função desolve seria:

          desolve([eqn_1, eqn_2], [f(x),g(x)]);

     Se as condições iniciais em x=0 forem conhecidas, poderão ser fornecidas antes de usar desolve, através de atvalue.

          (%i1) 'diff(f(x),x)='diff(g(x),x)+sin(x);
                           d           d
          (%o1)            -- (f(x)) = -- (g(x)) + sin(x)
                           dx          dx
          (%i2) 'diff(g(x),x,2)='diff(f(x),x)-cos(x);
                            2
                           d            d
          (%o2)            --- (g(x)) = -- (f(x)) - cos(x)
                             2          dx
                           dx
          (%i3) atvalue('diff(g(x),x),x=0,a);
          (%o3)                           a
          (%i4) atvalue(f(x),x=0,1);
          (%o4)                           1
          (%i5) desolve([%o1,%o2],[f(x),g(x)]);
                            x
          (%o5) [f(x) = a %e  - a + 1, g(x) =

                                                          x
                                             cos(x) + a %e  - a + g(0) - 1]
          (%i6) [%o1,%o2],%o5,diff;
                       x       x      x                x
          (%o6)   [a %e  = a %e , a %e  - cos(x) = a %e  - cos(x)]

     Se desolve não pode obter uma solução, retorna false.

 -- Função: ic1 (SOLUÇÃO, XVAL, YVAL)
     Resolve problemas de valor inicial para equações diferenciais de primeira ordem.  Aqui SOLUÇÃO é uma solução geral para a equação, na forma dada por ode2, XVAL dá um valor inicial para a variável independente, na forma X = X0, e YVAL dá o valor inicial para a variável dependente, na forma Y = Y0.

     Veja um exemplo da sua utilização na documentação de ode2.

 -- Função: ic2 (SOLUÇÃO, XVAL, YVAL, DVAL)
     Resolve problemas de valores iniciais para equações diferenciais de segunda ordem. Aqui SOLUÇÃO é uma solução geral para a equação, na forma dada por ode2, XVAL dá um valor inicial para a variável independente, na forma X = X0, YVAL dá o valor inicial para a variável dependente, na forma Y = Y0 e DVAL dá o valor inicial para a primeira derivada da variável dependente, em função da variável independente, na forma diff(Y,X) = DY0 (diff não tem que ser precedido por apóstrofo).

     Veja um exemplo da sua utilização na documentação de ode2.

 -- Função: ode2 (EQN, DVAR, IVAR)
     A função ode2 resolve uma equação diferencial ordinária (EDO) de primeira ou de segunda ordem.  Precisa de três argumentos: uma EDO dada por EQN, a variável dependente DVAR, e a variável independente IVAR.  Quando conseguir, retorna uma solução para a variável dependente, na forma explícita ou implícita. %c é usado para representar a constante de integração no caso de equações de primeira ordem, e %k1 e %k2 as constantes para equações de segunda ordem. A dependência da variável dependente na variável independente não tem que ser escrita em forma explícita, como no caso de desolve, mas a variável independente deverá ser indicada sempre no terceiro argumento.

     Se por alguma razão ode2 não conseguir encontrar a solução, retornará false, após talvez mostrar uma mensagem de erro. Os métodos implementados para equações diferenciais de primeira ordem, na ordem em que serão testados, são: linear, separável, exacta - talvez requerendo um factor de integração, homogénea, equação de Bernoulli, homogénea generalizada. Os tipos de equações de segunda ordem que podem ser resolvidas são: coeficientes constantes, exactas, linear homogéneas com coeficientes não-constantes que possam ser transformados para constates, equação de Euler ou equi-dimensional, equações que possam ser resolvidas pelo método de variação dos parâmetros, e equações que não dependam ou da variável independente ou da variável dependente de modo que possam ser reduzidas a duas equações lineares de primeira ordem a serem resolvidas sequêncialmente.

     Durante o processo de resolução da EDO, serão dados valores a várias variáveis locais, com fins puramente informativos: método denota o método de solução usado (por exemplo, linear), intfactor denota qualquer factor integrante utilizado, odeindex denota o índice para o método de Bernoulli ou para o método homogéneo generalizado, e yp denota a solução particular no método de variação dos parâmetros.

     Para resolver problemas de valores iniciais (PVI) estão disponíveis as funções ic1 e ic2e, para equações de primeira e segunda ordem, e para resolver problemas de valores fronteira (PVF) de segunda ordem pode usar-se a função bc2.

     Exemplo:

          (%i1) x^2*'diff(y,x) + 3*y*x = sin(x)/x;
                                2 dy           sin(x)
          (%o1)                x  -- + 3 x y = ------
                                  dx             x
          (%i2) ode2(%,y,x);
                                       %c - cos(x)
          (%o2)                    y = -----------
                                            3
                                           x
          (%i3) ic1(%o2,x=%pi,y=0);
                                        cos(x) + 1
          (%o3)                   y = - ----------
                                             3
                                            x
          (%i4) 'diff(y,x,2) + y*'diff(y,x)^3 = 0;
                                   2
                                  d y      dy 3
          (%o4)                   --- + y (--)  = 0
                                    2      dx
                                  dx
          (%i5) ode2(%,y,x);
                                3
                               y  + 6 %k1 y
          (%o5)                ------------ = x + %k2
                                    6
          (%i6) ratsimp(ic2(%o5,x=0,y=0,'diff(y,x)=2));
                                       3
                                    2 y  - 3 y
          (%o6)                   - ---------- = x
                                        6
          (%i7) bc2(%o5,x=0,y=1,x=1,y=3);
                                   3
                                  y  - 10 y       3
          (%o7)                   --------- = x - -
                                      6           2