dnl ### Normal initialization. ######################################
AC_INIT([pam_per_user], [0.4])
AC_PREREQ([2.57])
AC_CONFIG_AUX_DIR([autoconf])
AC_CONFIG_HEADERS([config.h])
AC_COPYRIGHT([[
Copyright (c) 2001-2003 University of Illinois Board of Trustees
Copyright (c) 2001-2005 Mark D. Roth
All rights reserved.
]])
AC_CONFIG_SRCDIR([pam_per_user.c])
ENCAP_PKG


dnl ### Set some option defaults. ###################################
if test -z "$CFLAGS"; then
  CFLAGS="-O"
fi
MKDIR="mkdir -p -m 755"
AC_SUBST([MKDIR])


dnl ### Check for compiler et al. ###################################
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET


dnl ### Compiler characteristics. ##################################
AC_AIX
AC_C_CONST


dnl ### Checks for header files. ###################################
AC_HEADER_STDC
AC_CHECK_HEADERS([unistd.h])
AC_CHECK_HEADERS([security/pam_appl.h],
  [],
  [AC_MSG_ERROR([PAM header files not found])],
  []
)
AC_CHECK_HEADERS([security/pam_modules.h],
  [],
  [AC_MSG_ERROR([PAM header files not found])],
  [#include <security/pam_appl.h>]
)


dnl ### Checks for needed functions. ###############################
PSG_MODULE([compat])
COMPAT_FUNC_SNPRINTF
COMPAT_FUNC_STRLCPY


dnl ### Check for libraries. #######################################
AC_CHECK_LIB([dl], [dlopen])
AC_CHECK_LIB([pam], [pam_start], [],
  [AC_MSG_ERROR([PAM library not found])]
)
PSG_SHLIB([
  #include <security/pam_appl.h>
], [ 
  pam_handle_t *pamh;
  struct pam_conv *conv = NULL;
  pam_start("conftest", "root", conv, &pamh);
])
if test "$wsg_cv_cflags_shlib" = "no" || test "$wsg_cv_ldflags_shlib" = "no"; then
  AC_MSG_ERROR([cannot create shared libraries])
fi


dnl ### Create output files. #######################################
AC_CONFIG_FILES([Makefile])
AC_OUTPUT