dnl
dnl  Configuration input file for standard Harvest broker components
dnl
dnl  $Id: configure.in,v 2.9 2000/02/03 12:45:54 sxw Exp $
dnl

AC_PREREQ(2.12)

AC_INIT(glimpse/main.c)
AC_REVISION(1.7)dnl
AC_PREFIX_DEFAULT(/usr/local/harvest)

dnl Build a copy of prefix

if test "X$prefix" != "XNONE"; then
  myprefix="$prefix";
else
  myprefix='/usr/local/harvest';
fi

INSTALL_TOPDIR="$myprefix";
INSTALL_LIBDIR="$myprefix/lib";
INSTALL_BINDIR="$myprefix/bin";
INSTALL_MANDIR="$myprefix/man";

THIS_HOST="`hostname`"
XTRA_LIBS=''


dnl Subsitutions
AC_SUBST(INSTALL_TOPDIR)
AC_SUBST(INSTALL_LIBDIR)
AC_SUBST(INSTALL_BINDIR)
AC_SUBST(INSTALL_MANDIR)
AC_SUBST(THIS_HOST)

dnl Stop it from setting optimisation
CFLAGS=''

dnl Check for GNU cc
AC_PROG_CC

dnl Check for programs
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_RANLIB

dnl look for true/false scripts first
AC_PATH_PROG(CMD_TRUE, true)
AC_PATH_PROG(CMD_FALSE, false)

dnl and use them
AC_PATH_PROG(CMD_GZIP, gzip, $CMD_FALSE)
AC_PATH_PROG(CMD_GUNZIP, gunzip, $CMD_FALSE)
AC_PATH_PROG(CMD_PERL, perl, $CMD_FALSE)

dnl Set PERL too
PERL="$CMD_PERL"
AC_SUBST(PERL)

dnl find ln -s
AC_PROG_LN_S

dnl Decide if we should really use -lmalloc.  It is known to have
dnl problems on SunOS 5.4 at least.
dnl
if test -x "/bin/uname"; then
        if /bin/uname -sr | grep ['SunOS 5.[0-4]'] >/dev/null 2>&1; then
                NO_LIBMALLOC=x
        fi
fi

dnl Check for needed libraries

if test x$NO_LIBMALLOC = x ; then
	AC_CHECK_LIB(malloc, main, [XTRA_LIBS="$XTRA_LIBS -lmalloc"])
fi


AC_CHECK_LIB(resolv, main, [XTRA_LIBS="$XTRA_LIBS -lresolv"])
AC_CHECK_LIB(socket, setsockopt, [XTRA_LIBS="$XTRA_LIBS -lsocket"])
AC_CHECK_LIB(nsl, gethostname, [XTRA_LIBS="$XTRA_LIBS -lnsl"])

dnl We found a version of libresolv on SunOS 4.x which requires -l44bsd
dnl We have to first check to see if -l44bsd is present and has the
dnl function inet_aton
AC_CHECK_LIB(44bsd, inet_aton, [HAVE_44BSD="yes"])
AC_CHECK_LIB(resolv, inet_aton, [if test "$HAVE_44BSD" = "yes"; then XTRA_LIBS="$XTRA_LIBS -l44bsd"; fi])

dnl Override XTRA_LIBS
if test -n "$XTRA_LIBS_OVERRIDE"; then
  XTRA_LIBS="$XTRA_LIBS_OVERRIDE";
fi
AC_SUBST(XTRA_LIBS)

dnl Try to see if we're on HP-UX or not
if test -x "/bin/uname"; then
        XXMyOs=`/bin/uname`;
        if test "HP-UX" = "$XXMyOs"; then
                RANLIB=":";
        fi
fi

dnl Clean up after OSF/1 core dump bug
rm -f core

AC_OUTPUT(\
	Makefile \
	WWW/Makefile \
	WWW/brokerAdmin \
	WWW/displaySOIF \
	WWW/search \
	glimpse/Makefile \
	glimpse/glimpseindex.sh \
	glimpse/agrep/Makefile \
	glimpse/index/Makefile \
	glimpse/compress/Makefile \
)