#! /usr/bin/perl -w

# vim:syntax=perl

use strict;
use lib '/usr/local/share/perl5';
use Lire::DlfSchema;
use Lire::Syslog;
use Lire::Firewall qw/ firewall_number2names /;
use Lire::Program qw( :msg :dlf );

my %action2cisco =
  (
   'b'      => "denied",
   'a'      => "permitted",
  );


init_dlf_converter( "firewall" );
my $schema = Lire::DlfSchema::load_schema( "firewall" );
my $dlf_maker = $schema->make_hashref2asciidlf_func(
   qw/time rule action protocol from_host from_ip from_port rcv_intf to_host to_ip to_port length count/
);

my ($lines, $dlflines, $errorlines) = (0, 0, 0);
my $parser = new Lire::Syslog;

while (<>) {
    chomp;

    $lines++;
    my $log = eval { $parser->parse($_) };
    if ($@) {
	lr_warn( $@ );
	lr_notice( qq{cannot convert line $. "$_" to firewall dlf, skipping} );
	$errorlines++;
	next;
    }

    # skip syslog lines which aren't related to ipfilter stuff
    next unless defined $log->{'process'} && $log->{'process'} eq 'ipmon';

    my %dlf;
    $dlf{time} = $log->{timestamp};

    # process stuff like:
    # 07:42:28.585962 ep1 @0:8 b 192.168.26.5,53 -> 192.168.26.1,2926 PR udp 
    #    len 20 70  OUT 
    my @line = split ' ', $log->{'content'};
    defined $line[0] and $dlf{'iptime'} = $line[0];

    $dlf{count} = 1;
    if (defined $line[1] and $line[1] =~ /^(\d+)x$/) {
        # print as many dlf's as the number indicates
        $dlf{count} = $1;
        shift @line;
    }

    defined $line[1] and $dlf{'rcv_intf'} = $line[1];
    defined $line[2] and $dlf{'rule'} = $line[2];
    defined $line[3] and $dlf{'action'} = $line[3]; # b or p
    if (defined $line[4]) {
	my ( $ip, $port ) = split /,/, $line[4];
	$dlf{from_port} =  $port;
	( $dlf{from_host}, $dlf{from_ip} ) =
	  $ip =~ /^(?:(.*)\[)?([.0-9]+)\]?$/;
    }
    defined $line[5] and ($line[5] eq '->' or 
        lr_warn("skipping line '$_': invalid format: fifth field " .
        "should be '->', not '". $line[5] ."'") and $errorlines++ and next);
    if (defined $line[6]) {
	my ( $ip, $port ) = split /,/, $line[6];
	$dlf{to_port} =  $port;
	( $dlf{to_host}, $dlf{to_ip} ) =
	  $ip =~ /^(?:(.*)\[)?([.0-9]+)\]?$/;
    }
    defined $line[7] and ($line[7] eq 'PR' or 
        lr_warn("skipping line '$_': invalid format: seventh field " .
        "should be 'PR', not '". $line[7] ."'") and $errorlines++ and next);
    defined $line[8] and $dlf{'protocol'} = $line[8]; # one of tcp, udp, icmp
    defined $line[9] and ($line[9] eq 'len' or 
        lr_warn("skipping line '$_': invalid format: nineth field " .
        "should be 'len', not '". $line[9] ."'") and $errorlines++ and next);

    if (defined $line[10] and defined $line[11]) {
        # sum lenght of header and lenght of packet

        # Jul  6 08:13:15 rolle ipmon[2658]: 08:13:15.373154 ep1 @0:7 b 
        #    100.187.115.1 -> 100.0.0.1 PR igmp len 24 (32) IN
        $line[11] =~ s/^[^\d]*(\d+)[^\d]*$/$1/;

        $dlf{'length'} = $line[10] + $line[11];
	$dlf{'length'} *= $dlf{'count'};
    }

    if (defined $line[12]) {
        if ($line[12] =~ /^-\w+$/) {
            $dlf{'flags'} = $line[12];
            defined $line[13] and $dlf{'direction'} = $line[13];
        } elsif ($line[12] eq 'icmp') {
            splice(@line, 0, 13);

            if ($line[-1] eq 'OUT' or $line[-1] eq 'IN') {
                $dlf{'direction'} = $line[-1];
                pop @line;
            }

            $dlf{'flags'} = join('_', @line);
        } else {
            defined $line[12] and $dlf{'direction'} = $line[12];
        }
    }

    $dlf{action} = $action2cisco{$dlf{action}} || $dlf{action};

    firewall_number2names( \%dlf );
    my $dlf = $dlf_maker->( \%dlf );

    print join( " ", @$dlf), "\n";
    $dlflines++;
}

end_dlf_converter( $lines, $dlflines, $errorlines );

__END__

=pod

=head1 NAME

ipfilter2dlf - convert ipf logs, as produced by ipmon, to Lire firewall DLF

=head1 SYNOPSIS

B<ipfilter2ldf>

=head1 DESCRIPTION

B<ipfilter2dlf> reads from stdin, writes dlf to stdout, and, in case of errors,
complains on stderr.  It expects an ipf logfile, as produced by Darren Reed's
IP Filter, on stdin.  IP Filter is shipped with FreeBSD, OpenBSD (up to 2.9)
and some other OS's.

=head1 EXAMPLE

A ipfilter logfile which looks like

 Oct 30 07:42:29 rolle ipmon[16747]: 07:42:28.585962              ie0 @0:9 
  b 192.168.48.1,45085 -> 192.168.48.2,22 PR tcp len 20 64 -S OUT 
 Oct 30 07:40:24 rolle ipmon[16747]: 07:40:23.631307              ep1 @0:6 
  b 192.168.26.5,113 -> 192.168.26.1,3717 PR tcp len 20 40 -AR OUT 
 Oct 30 07:42:29 rolle ipmon[16747]: 07:42:28.585962              ie0 @0:9 
  b 192.168.48.1,45085 -> 192.168.48.2,22 PR tcp len 20 64 -S OUT 
 Oct 30 07:44:11 rolle ipmon[16747]: 07:44:10.605416 2x              ep1 @0:15 
  b 192.168.26.1,138 -> 192.168.26.255,138 PR udp len 20 257  IN 
 Oct 30 07:44:34 rolle ipmon[16747]: 07:44:33.891869              ie0 @0:10 
  b 192.168.48.1,23406 -> 192.168.48.2,22 PR tcp len 20 64 -S OUT 
 Oct 30 07:49:13 rolle ipmon[16747]: 07:49:12.554420              ep1 @0:15 
  b 210.132.100.117 -> 192.168.26.5 PR icmp len 20 56 icmp 3/3 for 
  192.168.26.5,61915 - 210.132.100.117,53 PR udp len 20 23040 IN 
 Oct 30 07:50:23 rolle ipmon[16747]: 07:50:22.908107              ep1 @0:15 
  b 210.132.100.117 -> 192.168.26.5 PR icmp len 20 56 icmp 3/3 for 
  192.168.26.5,4480 - 210.132.100.117,53 PR udp len 20 19712 IN 
 Oct 30 07:56:11 rolle ipmon[16747]: 07:56:11.113029 2x              ep1 @0:15 
  b 192.168.26.1,138 -> 192.168.26.255,138 PR udp len 20 257  IN 

(that's: .... 'PR' protocol 'len' length_of_ip_headers_saved packetlength
direction) will get converted to something like

 994398737 denied igmp 100.187.115.1 - ep1 LIRE_NOTAVAIL 224.0.0.2 - 56
 994398861 denied igmp 100.187.115.1 - ep1 LIRE_NOTAVAIL 224.0.0.1 - 56
 994398862 denied igmp 100.187.115.1 - ep1 LIRE_NOTAVAIL 224.0.0.2 - 56
 994406849 denied udp 192.168.26.4 137 ie0 LIRE_NOTAVAIL 192.168.26.255 137 116
 994406850 denied udp 192.168.26.4 137 ie0 LIRE_NOTAVAIL 192.168.26.255 137 116
 994406866 denied udp 192.168.26.4 137 ie0 LIRE_NOTAVAIL 192.168.26.255 137 98

=head1 SEE ALSO

ipl(4) for description of log structure.

The ipmon.c source (e.g. on
http://www.openbsd.org/cgi-bin/cvsweb/~checkout~/src/usr.sbin/ipmon/Attic/ipmon.c?rev=1.27&content-type=text/plain&hideattic=0
for the specification) of the log syntax.

The IP Filter webpage on http://coombs.anu.edu.au/~avalon/ip-filter.html

=head1 VERSION

$Id: ipfilter2dlf.in,v 1.2 2002/08/19 00:27:41 flacoste Exp $

=head1 COPYRIGHT

Copyright (C) 2000-2001 Stichting LogReport Foundation LogReport@LogReport.org
 
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 2 of the License, or
(at your option) any later version.
 
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
GNU General Public License for more details.
 
You should have received a copy of the GNU General Public License
along with this program (see COPYING); if not, check with
http://www.gnu.org/copyleft/gpl.html or write to the Free Software 
Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111, USA.

=head1 AUTHOR

Joost van Baal <joostvb@logreport.org>

=cut

# Local Variables:
# mode: cperl
# End:
